昨天从vistape网站下载了最新的RunScanner1.0.0.25版，并相应更新l了Runscanner.ini
近日突然想到使用RunScanner运行程序很不方便，还不如做个GUI界面，于是写了个依托PECMD的INI文件。
主要功能就是代替命令行的输入方式，输入可执行程序名直接运行，并通过RunScanner重映射离线系统的注册表环境。支持一些常用参数的直接设置。
界面如下：
把本RUNSCANNER.INI文件同RunScanner程序放置于同一目录，然后用”PECMD LOAD RUNSCANNER.INI“就可以了。推荐设置键盘热键。
本窗口类似于运行窗口，会自动初始化位置到屏幕左下角。
下面是代码：
_SUB Window1,L5T%TPos%W%WinW%H%WinH%,%Title%,,RUNSCANNER.EXE,
IMAG Image1,L14T15W32H32,RUNSCANNER.EXE
LABE Label1,L60T20W300H32,RunScanner将根据您输入的名称，运行相应的可执行程\n序，并为其重映射离线系统的注册表环境。
LABE Label2,L14T60W32H20,打开:
LABE Label3,L14T89W32H20,选项:
CHEK Check1,L60T85W78H20,子进程继承,,1
CHEK Check2,L144T85W117H20,自动选择用户配置,,1
CHEK Check3,L264T85W104H20,不弹出默认提示,,1
CHEK Check4,L60T110W130H20,自定义Windows路径：,CALL BrowWindows,0
EDIT Edit2,l190t112w75h20,←点击选择,,2
ITEM Button1,L115T140W80H26,确定,CALL RUNExe
ITEM Button2,L200T140W80H26,取消,KILL \%Title%
ITEM Button3,L285T140W80H26,浏览...,CALL BrowExe
EDIT Edit1,l60t55w300h20,,CALL RUNExe
_END
_SUB BrowExe
BROW ExeFile,,请选择一个可执行程序文件,EXE
IFEX %ExeFile%,ENVI @Edit1=%ExeFile%
_END
_SUB BrowWindows
IFEX $%Check4.Check%=0,TEAM ENVI @Edit2=←点击选择|EXIT _SUB
ENVI FileData=
BROW WindowsDir,*%Edit2%,请选择目标系统的Windows文件夹,,0x200
IFEX %WindowsDir%\system32\config\SAM,GETF %WindowsDir%\system32\config\SAM,0x00#1,FileData
FIND $%FileData%=,TEAM MESS 请选择正确的Windows目录！\n注意：目标系统必须是离线系统。@错误：#OK*3000|ENVI @Check4.Check=0|ENVI @Edit2=←点击选择!ENVI @Edit2=%WindowsDir%
_END
_SUB RUNExe
FIND $%Edit1%=,EXIT _SUB
CALL GetPram
EXEC "%CurDir%\RUNSCANNER.EXE" %Pram% "%Edit1%"
KILL \%Title%
_END
_SUB GetPram
ENVI Pram=/t 0
IFEX $%Check1.Check%=1,ENVI Pram=%Pram% /cp
IFEX $%Check2.Check%=1,ENVI Pram=%Pram% /ac /m+
IFEX $%Check3.Check%=1,ENVI Pram=%Pram% /y
IFEX $%Check4.Check%=1,ENVI Pram=%Pram% /w "%Edit2%"!ENVI Pram=%Pram% /sd
_END
ENVI Title=RUNSCANNER 运行
KILL \%Title%
ENVI WinW=380
ENVI WinH=200
SCRN ScrW,ScrH
REGI #HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced\TaskbarSmallIcons,IsSmall
FIND $%IsSmall%=0x00000000,ENVI TaskBarH=45!ENVI TaskBarH=32
CALC #TPos=%ScrH%-%WinH%-%TaskBarH%
CALL @Window1
然后是含RunScanner程序的压缩包，内含RUNSCANNER.INI文件